//configuration variables
float ballDiameter = 10;
float brickWidth = 50;
float brickHeight = 20;
float paddleWidth = brickWidth*1.5;
float paddleHeight = brickHeight;
int numBrickRows = 10;

Brick[] bricks = new Brick[0];
Paddle myPaddle;
Ball myBall;

void setup() {
  size(500, 400);
  smooth();

  //place bricks
  for (int j=0; j<numBrickRows; j++) {
    //location of each row
    float y = brickHeight/2 + j* brickHeight;
    //set the row offset
    float offset = 0;
    if (j%2==0) {
      offset = brickWidth/2;
    }
    for (int i=int (offset); i<=width; i+=int(brickWidth)) {
      bricks = (Brick[]) append(bricks, new Brick(i, y));
    }
  }

  //create paddle
  myPaddle = new Paddle();
}

//standard draw() function
void draw() {
  background(255);

  //draw bricks
  for (int i=0; i<bricks.length; i++) {
    if (bricks[i] != null) {
      bricks[i].draw();
    }
  }

  //draw and update ball
  if (myBall!=null) {
    myBall.draw();
    myBall.update();
  }

  //draw paddle
  myPaddle.display();

  //test for ball impact with paddle
  if ( myBall!=null && myPaddle.impact(myBall) ) {
    //bounce ball
    myBall.bounce();
    //impart x velocity from paddle
    myPaddle.impartXVelocity(myBall);
  }

  //test for ball impact with brick
  if (myBall!=null) {
    for (int i=0; i<bricks.length; i++) {
      if (bricks[i]!=null && bricks[i].impact(myBall)) {
        //bounce the ball
        myBall.bounce();
        //delete brick
        bricks[i] = null;
      }
    }
  }

  //bounce ball with above screen
  if (myBall != null && myBall.y - ballDiameter/2<0) {
    myBall.bounce();
  }

  //enable new ball if the ball is lost 
  if (myBall != null && myBall.y - ballDiameter/2 > height) {
    myBall = null;
  }    

  //test and see if the player wins
  boolean weHaveWon=true;
  for (int i =0; i<bricks.length; i++) {
    if (bricks[i]!=null) {
      weHaveWon = false;
      break;
    }
  }

  if (weHaveWon) {
    println("YOU'VE WON!");
    exit();
  }
}

//mouseClicked function
void mouseClicked() {
  //create ball
  if (myBall == null)
    myBall = new Ball(myPaddle.x, height-paddleHeight-ballDiameter/2, 0, -2);
}


//The ball for the brickbreaker game
class Ball {
  float x;
  float y;
  float vx;
  float vy;

  //constructor
  Ball(float x, float y, float vx, float vy) {
    this.x = x;
    this.y = y;
    this.vx = vx;
    this.vy = vy;
  }

  //draw the ball
  void draw() {
    fill(0);
    ellipse(x, y, ballDiameter, ballDiameter);
  }

  //update the position of the ball, including bounces off the walls
  void update() {
    //update the position
    x = x+vx;
    y = y+vy;
    //bounce off
    if (x>width || x<0) {
      vx *= -1;
    }
  }
  
  //bounce off the paddle
  void bounce(){
    vy *= -1; //vy = vy*-1; 
  }
  
}

class Brick {
  float x;
  float y;
  color c;

  Brick(float x, float y) {
    this.x = x;
    this.y = y;
    c = color(random(255), random(255), random(255));
  }

  void draw() {
    rectMode(CENTER);
    fill(c);
    rect(x, y, brickWidth, brickHeight);
  }

  //Detect whether the ball impacts the brick
  boolean impact(Ball b) {
    if (x-brickWidth/2<=b.x && b.x<= x+brickWidth/2 && y+brickHeight/2>=b.y-ballDiameter/2)
      return true;
    else 
      return false;
  }
}

class Paddle {
  float x = mouseX;
  float y = height - paddleHeight/2;
  //PVector v = new PVector(mouseX, height - paddleHeight/2);
  float xPrePos;

  void display() {
    fill(0);
    xPrePos = x;
    //xPrePos = v.x;
    x = mouseX;
    //v.x= mouseX;
    rect(x, y, paddleWidth, paddleHeight);
    //rect(v.x, v.y, paddleWidth, paddleHeight);
  }

  boolean impact(Ball b) {
    if (b.x>=x-paddleWidth/2 &&
      b.x <= x + paddleWidth/2 &&
      b.y+ballDiameter/2 >y-paddleHeight/2)
      return true;
    else 
      return false;
  }

  void impartXVelocity(Ball b) {
    float xVector = x - xPrePos;
    b.vx += xVector;
  }
}