void setup() {
  size(1000, 1000);
  background(0);
  noStroke();
  translate(width/2, height/2);
  int pointCount = 8;
  int steps = 50;
  float outerRadius = width*.5;
  float innerRadiusFactor = .7;
  float innerRadius = outerRadius*innerRadiusFactor;
  float outerRadiusRatio = outerRadius/steps;
  float innerRadiusRatio = innerRadius/steps;
  float shadeRatio = 255.0/steps;
  float rotationRatio = 45.0/steps;
  star(pointCount, outerRadius-outerRadiusRatio, innerRadius-innerRadiusRatio);
  for (int i=0; i<steps; i++) {
    stroke(255-shadeRatio*i, 100);
    fill(shadeRatio*i);
    pushMatrix();
    rotate(rotationRatio*i*PI/180);
    star(pointCount, outerRadius-outerRadiusRatio*i, innerRadius-innerRadiusRatio*i);
    popMatrix();
  }
}

/** Draw a star based on the center point, inner radius and outer radius.
 *
 * @param pointCount number of outer points
 * @param innerRadius inner radius
 * @param outerRadius outer radius
 */ 
void star(int pointCount, float innerRadius, float outerRadius) {
  float theta = 0.0;
  // point count is 1/2 of total vertex count
  int vertCount = pointCount*2;
  float thetaRot = TWO_PI/vertCount;
  float tempRadius = 0.0;
  float x = 0.0, y = 0.0;
  beginShape();
  for (int i=0; i<pointCount; i++) {
    for (int j=0; j<2; j++) {
      tempRadius = innerRadius;
      // true if j is even
      if (j%2==0) {
        tempRadius = outerRadius;
      }
      x = cos(theta)*tempRadius;
      y = sin(theta)*tempRadius;
      vertex(x, y);
      theta += thetaRot;
    }
  }
  endShape(CLOSE);
} // end star